LED MA TRẬN 8x32

[nhungnguyen122]

LED MA TRẬN 8x32

http://youtu.be/uSQm2QMW0iY

$MOD51
ORG 00H ;DINH DIA CHI BAT DAU
MAIN:
LCALL NHAPMACOT ;GOI CTC NHAP MA COT
LCALL CHAY_CHU_RL ;GOI CTC CHAY CHU PHAI QUA TRAI
LCALL CHAY_CHU_LR ;GOI CTC CHAY CHU TRAI QUA PHAI
LJMP MAIN
NHAPMACOT: ;CTC NHAP MA COT
MOV R1,#50H ;GAN R1=50H
MOV DPTR,#MACOT ;DINH VI TRI CON TRO TAI DU LIEU MACOT
L00P1:
CLR A ;XOA A
MOVC A,@A+DPTR ;GAN A=@(A+DPTR)
MOV @R1,A ;GAN @R1=A
INC R1 ;R1=R1+1
INC DPTR ;TANG CON TRO THEM 1
CJNE R1,#70H,L00P1 ;SO SANH R1=70 :SAI NHAY LOOP1,DUNG TIEP TUC
RET ;KET THUC CTC NHAP MA COT
CHAY_CHU_RL: ; CTC CHAY CHU TU PHAI SANG TRAI - RL
MOV DPTR,#DULIEUHANG_RL ;DINH VI TRI CON TRO TAI DULIEUHANG_RL
MOV R3,#134 ;GAN R1=134 (134 LA SO BYTE TRONG DULIEUHANG_RL)
L00P2:
MOV R2,#10 ;GAN R2=10 TANG GIAM THOI GIAN HIEN THI
L00P3:
LCALL HIENTHI_RL ;GOI CTC HIENTHI_RL
DJNZ R2,L00P3 ;R2=R2-1 SO SANH R2=0:SAI NHAY LOOP3,DUNG TIEP TUC
INC DPTR ;TANG CON TRO THEM 1
DJNZ R3,L00P2 ;R3=R3-1 SO SANH R3=0:SAI NHAY LOOP2,DUNG TIEP TUC
RET ;KET THUC CTC CHAY_CHU_RL
HIENTHI_RL: ;CTC HIENTHI_RL
PUSH DPH ;CAT BYTE CAO CUA DPTR VAO NGAN XEP
PUSH DPL ;CAT BYTE THAP CUA DPTR VAO NGAN XEP
MOV R1,#50H ;GAN R1=50H
MOV R6,#32 ;GAN R6=32
L00P_RL4:
CLR A ;XOA A
MOVC A,@A+DPTR ;GAN A=@(A+DPTR)
LCALL XUATMACOT_RL ;GOI CTC XUATMACOT_RL
MOV P3,B ;GAN P3=B,XUAT P3
MOV P2,A ;GAN P2=A, XUAT P2
LCALL DELAY ;GOI CTC DELAY
INC DPTR ;TANG CON TRO THEM 1
DJNZ R6,L00P_RL4 ;R6=R6-1,SO SANH R6=0:SAI NHAY LOOP_RL4,DUNG TIEP TUC
POP DPL ;LAY LAI BYTE THAP DPTR
POP DPH ;LAY LAI BYTE CAP DPTR
RET ;KET THUC CTC

XUATMACOT_RL: ;CTC XUATMACOT_RL
MOV B,@R1 ;GAN B=@R1
INC R1 ;R1=R1+1
CJNE R1,#70H,THOAT_RL ;SO SANH R1=70H,DUNG NHAY THOAT_RL,SAI TIEP TUC
MOV R1,#50H ;GAN R1=50H
THOAT_RL:
RET ;KET THUC CTC
　
　
CHAY_CHU_LR: ;CTC CHAY CHU TU TRAI SANG PHAI - LR
MOV DPTR,#DULIEUHANG_LR ;DINH VI TRI CON TRO TAI DULIEUHANG_LR
MOV R3,#67 ;GAM R3=67
L00P_LR2:
MOV R2,#10 ;GAN R2=10
L00P_LR3:
LCALL HIENTHI_LR ;GOI CTC HIENTHI_LR
DJNZ R2,L00P_LR3 ;R2=R2-1,SO SANH R2=0:SAI NHAY LOOP_LR3,DUNG TIEP TUC
INC DPTR ;TANG CON TRO THEM 1
DJNZ R3,L00P_LR2 ;R3=R3-1,SO SANH R3=0:SAI NHAY LOOP_LR2, DUNG TIEP TUC
RET ;KET THUC CTC
HIENTHI_LR: ;CTC HIENTHI_LR
PUSH DPH ;CAT BYTE CAO CUA DPTR VAO NGAN XEP
PUSH DPL ;CAT BYTE THAP CUA DPTR VAO NGAN XEP
MOV R1,#6FH ;GAN R1=6FH
MOV R6,#32 ;GAN R6=32
L00P_LR4:
CLR A ;XOA A
MOVC A,@A+DPTR ;GAN A=@(A+DPTR)
LCALL XUATMACOT_LR ;GOI CTC XUATMACOT_LR
MOV P3,B ;GAN P3=B,XUAT P3
MOV P2,A ;GAN P2=A,XUAT P2
LCALL DELAY ;GOI CTC DELAY
INC DPTR ;TANG CON TRO DU LIEU THEM 1
DJNZ R6,L00P_LR4 ;R6=R6-1,SO SANH R6=0:SAI NHAY LOOP_LR4,DUNG TIEP TUC
POP DPL ;LAY LAI BYTE THAP CUA DPTR
POP DPH ;LAY LAI BYTE CAO CUA DPTR
RET ;KET THUC CTC

XUATMACOT_LR: ;CTC XUATMACOT_LR
MOV B,@R1 ;GAN B=@R1
DEC R1 ;GIAM R1=R1-1
CJNE R1,#4FH,THOAT_LR ;SO SANH R1=4FH,DUNG THOAT_LR,SAI TIEP TUC
MOV R1,#6FH ;GAN R1=6FH
THOAT_LR:
RET ;KET THUC CTC
　


DELAY:
MOV R5,#15
L00P5:
MOV R4,#15
DJNZ R4,$
DJNZ R5,L00P5
RET
　
DULIEUHANG_RL:
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,00H,00H,0E7H,0E7H,00H,00H,0FFH ;H
DB 0FFH,80H,00H,3FH,3FH,00H,80H,0FFH ;U
DB 0FFH,00H,00H,0F9H,0F3H,00H,00H,0FFH ;N
DB 0FFH,81H,00H,3CH,2CH,0CH,8DH,0FFH ;G
DB 0FFH,0E7H,0E7H,0E7H,0E7H,0FFH ;-
DB 0FFH,00H,00H,0F9H,0F3H,00H,00H,0FFH ;N
DB 0FFH,00H,00H,0FFH ;I
DB 0FFH,00H,00H,24H,24H,24H,0FFH ;E
DB 0FFH,00H,00H,0F9H,0F3H,0F9H,00H,00H,0FFH ;M

DB 0FFH,0E7H,0E7H,0E7H,0E7H,0FFH ;-
DB 0FFH,00H,00H,3FH,3FH,3FH,0FFH ;L
DB 0FFH,80H,00H,3FH,3FH,00H,80H,0FFH ;U
DB 0FFH,03H,01H,0CCH,0CCH,01H,03H,0FFH ;A
DB 0FFH,00H,00H,0F9H,0F3H,00H,00H,0FFH ;N
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
　
DULIEUHANG_LR:
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,0FCH,0FCH,00H,00H,0FCH,0FCH,0FFH ;T
DB 0FFH,0C3H,81H,3CH,3CH,00H,00H,0FFH ;D
DB 0FFH,00H,00H,0F3H,0F9H,00H,00H,0FFH ;N
DB 0FFH,0BDH,3CH,3CH,3CH,00H,81H,0FFH ;C
DB 0FFH,0FFH ;KHOANG TRANG

DB 0FFH,03H,01H,0CCH,0CCH,01H,03H,0FFH ;A
DB 0FFH,81H,00H,3CH,3CH,00H,81H,0FFH ;0
DB 0FFH,00H,00H,0E7H,0E7H,00H,00H,0FFH ;H
DB 0FFH,7EH,3CH,99H,0C3H,00H,00H,0FFH ;K
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH, 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH

MACOT:
DB 08H,09H,0AH,0BH,0CH,0DH,0EH,0FH
DB 10H,11H,12H,13H,14H,15H,16H,17H
DB 20H,21H,22H,23H,24H,25H,26H,27H
DB 40H,41H,42H,43H,44H,45H,46H,47H

END

Hình Capture :

http://i113.photobucket.com/albums/n238/hunglaser/led_matrix_8x32_capture.jpg

Hình Layout :

http://i113.photobucket.com/albums/n238/hunglaser/led_matrix_8x32_layout01.jpg

http://i113.photobucket.com/albums/n238/hunglaser/led_matrix_8x32_layout02.jpg

Hình Proteus

http://i113.photobucket.com/albums/n238/hunglaser/Capture-3.jpg

Download Led Matrix 8x32: (http://www.mediafire.com/?l8q56d4646ccu9h)
+ File ASM, Hex
+ File mô Phỏng led matrix 8x32
+ File Capture, Layout
+ Datasheet
+ Thư viện layout
+ Bài báo cáo